[Up][Contents][Index]

Information from Analysis

In the first instance this program is designed to take into account stratigraphic information from a site and modify the probability distributions obtained directly from radiocarbon calibration or other dating methods (called `prior' probability distributions) in the light of this additional data (producing so called `posterior' probability distributions). There are however other, equally important, types of information which can be obtained.

Times of the first and last dated events
Duration of phases and sequences
Using Boundaries
Interval between two events
The ordering of events
Reliability of stratigraphy
Correlation between two events

First and last dated events

For a given group of dates which may be constrained in some way by stratigraphic information it is useful to be able to obtain a probability distribution for the first and last members of the group. eg:

Sequence
{
 Boundary Start;
 Sequence
 {
  R_Date 800 35;
  Phase
  {
   First;
   R_Date 750 30;
   R_Date 800 35;
   Last;
  };
  R_Date 660 35;
 };
 Boundary End;
};

It should be stressed that to use this to estimate the start and end of phases relies on the fact that the distribution of dated samples within the group are representative of the archaeological phase in question. If no objects have been recovered from the first century of a period no amount of statistical analysis can determine when that period began! Furthermore if there are no dated events prior to the period and a large number of dated events within it statistical analysis is liable to indicate that the period started earlier than it actually did simply because of the inevitable scatter in the measurements. These caveats are no more or less relevant to non-mathematical methods of analysis and simply imply good archaeological practice in bracketing periods.

Duration of phases and sequences

The next type of information which one might wish to glean from the analysis is the span of a group of dates. A probability distribution can be generated which represents the difference in age between the first and last items in a group. eg.:

Sequence
{
 Boundary Start;
 Sequence
 {
  R_Date 800 35;
  Phase
  {
   R_Date 750 30;
   R_Date 800 35;
   Span;
  };
  R_Date 660 35;
 };
 Boundary End;
};

Clearly you should bear in mind the caveats mentioned in the preceding section.

Using Boundaries

The two previous sections outline one way in which a group of dated events can be treated in relation to archaeological phases. This approach assumes that the dated events are both well constrained and cover the archaeological phase from start to finish. An alternative approach is to assume that the deposition of dated artifacts is fairly uniform chronologically and use the distribution to estimate the boundaries of the archaeological phases using this model. This is the other function of the Boundary statement used to mark which samples come from a set period. eg:

Sequence
{
 Boundary Start;
 Phase
 {
  R_Date 750 30;
  R_Date 830 30;
  R_Date 820 30;
  R_Date 760 30;
  R_Date 810 30;
  R_Date 800 30;
 };
 Boundary End;
 Span;
};

Using such a model will give a much more realistic estimate of the phase boundaries than simply assuming that the events are unconstrained (ie not using Boundaries at all) and estimating when the first and last events took place. If the phase is well constrained anyway the results will be very similar.

Interval between two events

It is often useful to be able to find out what the interval between two phases or two events was. A probability distribution can be obtained for such events which follow one after the other in a sequence. For example the fragment:

Sequence
{
 R_Date 800 35;
 Interval;
 R_Date 660 35;
};

It is also possible to calculate a probability distribution for the difference between any two events in an analysis (Difference).

The ordering of events

Sometimes you may wish to estimate the probability of various possible orders of dated events. Assuming that the dating evidence is good enough to provide the necessary discrimination such probabilities can easily be calculated (Order).

Reliability of stratigraphy

Clearly any analysis relies very strongly on the reliability of the information included. The analysis does include the calculation of some overall indicators of how well all of the data incorporated in the analysis agrees and which elements of the data are most suspect. It is frequently the case that there is some uncertainty associated with the stratigraphic evidence for an item (or indeed the date measurement itself). In these cases it is necessary to be able to find out how likely an item is to be in a particular place in a chronological sequence. If the position of an item is questioned (Question) in this way the item will be ignored in the main analysis and a probability calculated. Consider for example the fragment:

Sequence
{
 R_Date 970 35;
 R_Date 1180 30?
 R_Date 930 35;
};

This would give a fairly low probability of being true (in fact 0.7%).

No provision has been made for assigning probabilities to the veracity of dated events as such a practice seems rather arbitrary and virtually impossible to justify.

Correlation between two events

The resultant probability distributions after analysis are not in general independent. For example two events in a sequence may have probability distributions which overlap but clearly given the fact that they are in a sequence the second one must always follow the first. It is, therefore, occasionally useful to be able to display a plot of one distribution relative to another. This is can be achieved (Correlation) although it should be said that the resultant two dimensional map needs some practice in interpretation.